なんでも作っちゃう、かも。

// Japanino POV by Musashinodenpa

#define LEDPIN 7     // どのピンからLEDをつなぐか
#define SWPIN  6     // スイッチをつなぐピン
#define WIDTH  20    // 表示する幅

// ビットマップ(画像)を定義
byte bitmap[] = {
  0b00000000,
  0b01000001,
  0b01111111,
  0b01000001,
  0b00000000,
  0b00000000,
  0b00001110,
  0b00011111,
  0b00111111,
  0b01111110,
  0b00111111,
  0b00011111,
  0b00001110,
  0b00000000,
  0b00000000,
  0b00111111,
  0b01000000,
  0b01000000,
  0b00111111,
  0b00000000,
};

unsigned long lastTime;
unsigned long aveTime;

void setup() {
  // LEDが接続されたピンを出力に設定します
  for(char pin = LEDPIN; pin < LEDPIN + 7; pin++) {
    pinMode(pin, OUTPUT);
  }
  pinMode(SWPIN, INPUT);      // スイッチのピンを入力に
  digitalWrite(SWPIN, HIGH);  // 内蔵プルアップ有効
}

void loop()
{
  // スイッチがオンならば1回描画
  if(digitalRead(SWPIN) == LOW) {
    unsigned long cur = millis();
    unsigned long dif = cur - lastTime;

    aveTime = (dif >> 1) + (dif >> 2) + (aveTime >> 2);
    lastTime = cur;

    if(aveTime > 500)
      aveTime = 500;

    unsigned short us = (aveTime * 500) / (WIDTH + 4);

    // すぐ始めると詰まって見えるのでちょっと待つ
    delayMicroseconds(us);
    delayMicroseconds(us);

    for(int pos=0; pos<WIDTH; pos++){
      for(int i = 0; i < 7; i++) {  // ビットマップの高さの分だけ繰り返し
        // ビットマップデータから1ビットを取り出してピンの状態に反映
        digitalWrite(LEDPIN + 6 - i, (bitmap[pos] >> i) & 0b00000001);
      }
      // LEDが光っている時間
      delayMicroseconds(us);
    }
    for(int i = LEDPIN; i < LEDPIN + 7; i++) {  // 全ドット、消灯
      digitalWrite(i, LOW);
    }
  }
}